File PKGBUILD of Package gnome-shell-extension-systemd-offline-update

# Maintainer: Sebastian Wiesner <sebastian@swsnr.de>

pkgname=gnome-shell-extension-systemd-offline-update
pkgver=49.0
pkgrel=1
pkgdesc='Gnome shell extension to indicate pending systemd offline updates'
arch=('any')
url="https://codeberg.org/swsnr/${pkgname}"
license=('EUPL-1.2')
depends=('gnome-shell')
makedepends=('typescript' 'just' 'git')
source=("git+${url}.git#tag=v${pkgver}")
sha256sums=('91fa3e20e5824f5a55fc8620dc47d229d36a28090c65c489a5a2e5745b225970')

build() {
    cd "${pkgname}" || exit 1
    just tsc=/usr/bin/tsc pack
}

package() {
    cd "${pkgname}" || exit 1

    local uuid
    uuid=systemd-offline-update@swsnr.de

    install -dm0755 "${pkgdir}/usr/share/gnome-shell/extensions/${uuid}"
    bsdtar xf "${uuid}.shell-extension.zip" \
        -C "${pkgdir}/usr/share/gnome-shell/extensions/${uuid}"
    rm "${pkgdir}/usr/share/gnome-shell/extensions/${uuid}/LICENSE"
    mv "${pkgdir}/usr/share/gnome-shell/extensions/${uuid}/locale" \
        "${pkgdir}/usr/share/locale"

    install -Dm0644 README.md "${pkgdir}/usr/share/doc/${pkgname}/README.md"
}