File PKGBUILD of Package wsl2-ssh-agent

# Maintainer: Sebastian Wiesner <sebastian@swsnr.de>
# Contributor: Zhong Lufan <lufanzhong@gmail.com>

pkgname=wsl2-ssh-agent
pkgver=0.9.7
pkgrel=1
pkgdesc="A bridge from WSL2 ssh client to Windows ssh-agent.exe service"
arch=('x86_64' 'aarch64')
url="https://github.com/mame/wsl2-ssh-agent"
license=('MIT')
makedepends=('go' 'git')
source=("git+${url}.git#tag=v${pkgver}"
        "vendor.tar.zst")
sha256sums=('d0d9db82999f6c976814e42dd4b74fc39640f69d59b41ea4c1caecccc6c44e45'
            'af13099abc55df8d8c42637d8b41cc551aabfaaa8b398afa476fdc4bbe06386a')

prepare() {
  cd "${pkgname}"
  ln -Tsf ../vendor ./vendor
}

build() {
  cd "${srcdir}/${pkgname}"

  export CGO_CPPFLAGS="${CPPFLAGS}"
  export CGO_CFLAGS="${CFLAGS}"
  export CGO_CXXFLAGS="${CXXFLAGS}"
  export CGO_LDFLAGS="${LDFLAGS}"

  go build \
    -trimpath \
    -buildmode=pie \
    -mod=vendor \
    -modcacherw \
    -ldflags "-linkmode external -extldflags \"${LDFLAGS}\"" \
    -o "${pkgname}"
}

package() {
  cd "${srcdir}/${pkgname}"
  install -Dm0755 -t "${pkgdir}/usr/bin" "${pkgname}"
}