File PKGBUILD of Package turnon

# Maintainer: Sebastian Wiesner <sebastian@swsnr.de>

pkgname=turnon
pkgver=2.6.0
pkgrel=1
pkgdesc='Turn on devices in your network'
arch=('x86_64')
url="https://github.com/swsnr/turnon"
license=('MPL-2.0')
# Dependencies are cargo-culted from
# https://gitlab.archlinux.org/archlinux/packaging/packages/obfuscate/-/blob/main/PKGBUILD?ref_type=heads
depends=(
    dconf
    gcc-libs
    glib2
    glibc
    graphene
    gtk4
    hicolor-icon-theme
    libadwaita
)
makedepends=('rust' 'cargo')
source=(
    "${url}/releases/download/v${pkgver}/${pkgname}-v${pkgver}.tar.zst"
    "${url}/releases/download/v${pkgver}/${pkgname}-v${pkgver}-vendor.tar.zst"
    config.toml
)
sha256sums=('f954d978fa387a33abff948452c936c827c29ba74fdc5ed089cbd7b0ef5f1160'
            'da30ae4d5d6d59d94a606941e3eba71346915668e0dda858d1a3950ccef783dc'
            '8dc330c974e99a362fd8d27f5d76f485da9559f80d576e0fd9ffb1779e4dd881')

prepare() {
    cd "${pkgname}-v${pkgver}" || return 1

    install -D -m644 "${srcdir}/config.toml" .cargo/config.toml
}

build() {
    cd "${pkgname}-v${pkgver}" || return 1
    SKIP_BLUEPRINT=1 cargo build --release --locked
    make msgfmt
}

package() {
    cd "${pkgname}-v${pkgver}" || return 1
    make DESTPREFIX="${pkgdir}/usr" install
}