File PKGBUILD of Package stardust-xr-server

pkgname="stardust-xr-server"
pkgver=0.51.1~0
pkgrel=0
pkgdesc="Usable Linux display server that reinvents human-computer interaction for all kinds of XR"
arch=("x86_64" "aarch64")
url="https://github.com/StardustXR/server"
license=("GPL-2.0-only")
depends=(
	"vulkan-icd-loader"
	"mesa"
	"libx11"
	"fontconfig"
	"libxkbcommon"
	"alsa-lib"
)
makedepends=(
	"rust"
	"cmake"
	"pkg-config"
)
provides=("stardust-server")
source=(
    "server-$pkgver.tar.zst"
    vendor.tar.zst
)
sha256sums=(
    'SKIP'
    'SKIP'
)
options+=(!lto !debug !strip)

prepare() {
    cd "$srcdir"
    for dir in "vendor" "Cargo.lock"; do
    	mv $dir "server-$pkgver"
    done
    { echo; cat ".cargo/config.toml"; } >> "server-$pkgver/.cargo/config.toml"
}

build() {
	cd "$srcdir/server-$pkgver"
	cargo build --release --target "${CARCH}-unknown-linux-gnu"
}

package() {
	cd "$srcdir/server-$pkgver"
	install -Dm755 \
		"target/${CARCH}-unknown-linux-gnu/release/${pkgname}" \
		"${pkgdir}/usr/bin/${pkgname}"
	install -Dm644 \
		LICENSE \
		"${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
	install -Dm644 \
		README.md \
		"${pkgdir}/usr/share/doc/${pkgname}/README.md"
}