File PKGBUILD of Package stardust-xr-solar-sailer

_clientname="solar-sailer"
pkgdesc="Momentum based playspace mover for Stardust XR"

pkgname="stardust-xr-$_clientname"
pkgver="0.50.0~0"
pkgrel="2"
arch=("x86_64" "aarch64")
url="https://github.com/StardustXR/$_clientname"
license=("MIT")
depends=()
makedepends=(
	"rust"
)
source=(
    "$_clientname-$pkgver.tar.zst"
    vendor.tar.zst
)
sha256sums=("SKIP" "SKIP")
OPTIONS=(strip lto !debug)

prepare() {
    cd "$srcdir"
    for dir in "vendor" ".cargo" "Cargo.lock"; do
    	mv $dir "$_clientname-$pkgver"
    done
}

build() {
    cd "$srcdir/$_clientname-$pkgver"
    export RUSTUP_TOOLCHAIN=stable
    export STARDUST_RES_PREFIXES="/usr/share/$pkgname"
    cargo build --frozen --release --target "$CARCH-unknown-linux-gnu"
}

package() {
	cd "$srcdir/$_clientname-$pkgver"
    install -Dm755 "target/$CARCH-unknown-linux-gnu/release/$_clientname" "$pkgdir/usr/bin/$_clientname"
    install -Dm644 \
		LICENSE \
		"$pkgdir/usr/share/licenses/$pkgname/LICENSE"
	install -Dm644 \
		README.md \
		"$pkgdir/usr/share/doc/$pkgname/README.md"
    cp -r "res/solar_sailer" "$pkgdir/usr/share/$pkgname"
}