File PKGBUILD of Package qdvdauthor

# Maintainer: Roland Suchan <snrd at arcor dot de>

pkgname=qdvdauthor
pkgver=2.3.1
pkgrel=15
pkgdesc='A GUI frontend for dvdauthor, video DVD creator'
url='https://sourceforge.net/projects/qdvd'
license=('GPL2')
arch=('x86_64')
depends=(
  'bash'
  'gcc-libs'
  'glibc'
  'qt5-base'
  'xine-lib'
  'vlc'
  'libx11'
  'libva' 'libva.so'
  'libglvnd' 'libGLX.so' 'libOpenGL.so'
  'bzip2' 'libbz2.so'
  'zlib' 'libz.so'
)
makedepends=(
  'qt5-tools'
  'cmake'
  'extra-cmake-modules'
)
provides=(
  'dvd-slideshow'
  'qdvdauthor'
  'qplayer'
  'qslideshow'
  'qrender'
)
source=(
  "https://sourceforge.net/projects/qdvd/files/qdvd-${pkgver}-qt5/qdvdauthor-${pkgver}-015.tar.gz"
  'https://ffmpeg.org/releases/ffmpeg-0.6.7.tar.bz2'
  'mathops_fix.patch'
)
sha256sums=(
  'b2f4a2f478776a11d8657f11b33429b3a222ba54d283a6a9b277b09645c52d5e'
  'SKIP'
  'SKIP'
)
options=('debug' '!lto')

prepare() {
  patch -d ffmpeg-0.6.7 -p1 -i "${srcdir}/mathops_fix.patch"
  #patch -d "$pkgname-$pkgver" -p1 -i "${srcdir}/found_ffmpeg.patch"
}

build() {
  cd ffmpeg-0.6.7

  CFLAGS="${CFLAGS} -Wno-implicit-function-declaration" \
  ./configure \
    --prefix="${srcdir}/qdvdauthor-${pkgver}/qrender/ffmpeg-0.6.7" \
    --disable-ffmpeg \
    --disable-ffplay \
    --disable-ffprobe \
    --disable-ffserver \
    --enable-pic \
    --disable-doc \
    --enable-static \
    --enable-shared

  make
  make install

  cd ..
  export PKG_CONFIG_LIBDIR="${srcdir}/qdvdauthor-${pkgver}/qrender/ffmpeg-0.6.7/lib/pkgconfig"
  export PKG_CONFIG_PATH="${PKG_CONFIG_LIBDIR}:/usr/lib/pkgconfig:/usr/share/pkgconfig"

  cmake -S "qdvdauthor-${pkgver}" -B build \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DFFMPEG_DIRS="${srcdir}/qdvdauthor-${pkgver}/qrender/ffmpeg-0.6.7"

  cmake --build build
}

package() {
  DESTDIR="${pkgdir}" cmake --install build
}