File PKGBUILD of Package exiv2

pkgname=exiv2
pkgver=0.28.0
pkgrel=3
pkgdesc="Exif, Iptc and XMP metadata manipulation library and tools"
url="https://exiv2.org"
arch=('x86_64')
license=('GPL2')
depends=('gcc-libs' 'zlib' 'expat' 'libexpat.so' 'gettext' 'curl' 'libcurl.so' 'libinih')
makedepends=('cmake' 'gtest' 'ninja')
checkdepends=('python')
provides=('libexiv2.so')
source=(https://github.com/Exiv2/exiv2/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz
        https://github.com/Exiv2/exiv2/commit/16c1cd7d.patch
        https://github.com/Exiv2/exiv2/commit/b4f435a4.patch
        https://github.com/Exiv2/exiv2/commit/f47e7bd6.patch
        https://github.com/Exiv2/exiv2/commit/3664f5b8.patch
        https://github.com/antermin/exiv2/compare/931a40a..823918e.patch)
sha512sums=('35e483c6123f099167ed8647fae7c6e5512434c24d0afe684180ba6a5114068d5678280a01c8e6cfee0d1e555e1dc2a1606989d46950ce3ef1a3859caeed4dad'
            'aa9a5e64d31579605ba3af4a076dc1df3bb4d07640716cbfeecd7a124059730445b5d468187e59e390fec58c03d9086b029ce0b2b563c8995d3df5af000ed37f'
            'b9b65766c02aa44ee26409c6e5d13bfd592ee94d7f757b60170e0e012efe4a75017cdccc190498084c8675018db07427158154ccaad1c882adbdfb2ea4d3cd25'
            '035e4a9ca11fbc8a858d5212c5663c2edc79168c50b614708bd7cfd50ca95751ff907001d3e43b08e33b070f36e27873734a19c03c6b63f104c7cb3b7cc84b14'
            '2871574012b11dcad02a1b2af45f11e0d4497163886adc140bc8ec6e4f9b0654c2a70aca71ab6c8dee7e4cf4a1da901da183a0acbc183f37e7a31ac11f1da0bd'
            'SKIP')

prepare() {
# Fix some 0.28 regressions
  patch -d $pkgname-$pkgver -p1 < 16c1cd7d.patch
  patch -d $pkgname-$pkgver -p1 < b4f435a4.patch
  patch -d $pkgname-$pkgver -p1 < f47e7bd6.patch
  patch -d $pkgname-$pkgver -p1 < 3664f5b8.patch

  patch -d ${pkgname}-${pkgver} -p1 -i $srcdir/931a40a..823918e.patch
}

build() {
  cd ${pkgname}-${pkgver}
  cmake -B build \
    -GNinja \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_SKIP_RPATH=ON \
    -DEXIV2_BUILD_SAMPLES=ON \
    -DEXIV2_BUILD_UNIT_TESTS=ON \
    -DEXIV2_ENABLE_VIDEO=ON \
    -DEXIV2_ENABLE_NLS=ON \
    -DEXIV2_ENABLE_XMP=ON \
    -DEXIV2_ENABLE_CURL=ON \
    -DEXIV2_ENABLE_WEBREADY=ON \
    -DEXIV2_ENABLE_BMFF=ON
  ninja -C build
}

check() {
  cd ${pkgname}-${pkgver}
  LD_LIBRARY_PATH="$PWD"/build/lib \
  ninja -C build test
}

package() {
  cd ${pkgname}-${pkgver}
  # remove samples instal which are only needed for unit tests
  sed '/samples\/cmake_install.cmake/d' -i build/cmake_install.cmake
  DESTDIR="${pkgdir}" ninja -C build install
}

# vim: ts=2 sw=2 et: