File PKGBUILD of Package intel-media-driver

pkgname=intel-media-driver
pkgver=20.1.1
pkgrel=1
pkgdesc="Intel Media Driver for VAAPI — Broadwell+ iGPUs"
arch=(x86_64)
url="https://github.com/intel/media-driver/"
license=(MIT BSD)
depends=(gcc-libs intel-gmmlib libva libpciaccess)
makedepends=(cmake)
source=("https://github.com/intel/media-driver/archive/intel-media-${pkgver}.tar.gz"
        "https://github.com/xhaihao/media-driver/commit/90d58541f8d1bf5abcbff2d3bf71ae26e54240c9.patch")
sha256sums=('SKIP'
            'SKIP')

export PKGEXT='.pkg.tar.zst'

prepare() {
    cd ${pkgname#*-}-${pkgname%-*}-${pkgver}
    patch -p1 -i ../90d58541f8d1bf5abcbff2d3bf71ae26e54240c9.patch
}

build() {
    cmake -B build -S ${pkgname#*-}-${pkgname%-*}-${pkgver} \
        -DCMAKE_INSTALL_PREFIX=/usr \
        -DCMAKE_INSTALL_LIBDIR=lib \
        -DINSTALL_DRIVER_SYSCONF=OFF \
        -Wno-dev
    make -C build -j$(nproc)
}

package() {
    make -C build DESTDIR="$pkgdir" install
    install -Dm644 ${pkgname#*-}-${pkgname%-*}-${pkgver}/LICENSE.md -t "${pkgdir}"/usr/share/licenses/${pkgname}/
}