openSUSE Build Service

Overview Repositories Revisions Requests Users Attributes Meta

File PKGBUILD of Package ffmpeg (Revision 55e43128fbae1eaa7a7c87ede8866b6d)

Currently displaying revision 55e43128fbae1eaa7a7c87ede8866b6d , Show latest

pkgname=ffmpeg
pkgver=6.1.1
pkgrel=3
epoch=2
pkgdesc='Complete solution to record, convert and stream audio and video'
arch=(x86_64)
url=https://ffmpeg.org/
license=(GPL3)
depends=(
  alsa-lib
  aom
  bzip2
  cairo
  fontconfig
  fribidi
  glib2
  glibc
  gmp
  gnutls
  gsm
  jack
  lame
  libass.so
  libavc1394
  libbluray.so
  libbs2b.so
  libdav1d.so
  libdrm
  libfreetype.so
  libgl
  libharfbuzz.so
  libiec61883
  libjxl.so
  libmodplug
  libopenmpt.so
  libplacebo.so
  libpulse
  librav1e.so
  libraw1394
  librsvg-2.so
  librubberband.so
  libsoxr
  libssh
  libtheora
  libva.so
  libva-drm.so
  libva-x11.so
  libvdpau
  libvidstab.so
  libvorbisenc.so
  libvorbis.so
  libvpx.so
  libwebp
  libx11
  libx264.so
  libx265.so
  libxcb
  libxext
  libxml2
  libxv
  libxvidcore.so
  libzimg.so
  ocl-icd
  onevpl
  opencore-amr
  openjpeg2
  opus
  sdl2
  snappy
  speex
  srt
  svt-av1
  v4l-utils
  vmaf
  vulkan-icd-loader
  xz
  zlib
)
makedepends=(
  amf-headers
  avisynthplus
  clang
  ffnvcodec-headers
  frei0r-plugins
  git
  ladspa
  mesa
  nasm
  opencl-headers
  vulkan-headers
  mold
  llvm
)
optdepends=(
  'avisynthplus: AviSynthPlus support'
  'frei0r-plugins: Frei0r video effects support'
  'intel-media-sdk: Intel QuickSync support (legacy)'
  'ladspa: LADSPA filters'
  'nvidia-utils: Nvidia NVDEC/NVENC support'
  'onevpl-intel-gpu: Intel QuickSync support'
)
provides=(
  libavcodec.so
  libavdevice.so
  libavfilter.so
  libavformat.so
  libavutil.so
  libpostproc.so
  libswresample.so
  libswscale.so
)
_tag=6f4048827982a8f48f71f551a6e1ed2362816eec
source=("https://github.com/FFmpeg/FFmpeg/archive/n${pkgver}.tar.gz"
        "add-av_stream_get_first_dts-for-chromium.patch"
        "https://github.com/FFmpeg/FFmpeg/commit/e9c93009fc34ca9dfcf0c6f2ed90ef1df298abf7.patch"
        "https://github.com/FFmpeg/FFmpeg/commit/a562cfee2e214252f8b3f516527272ae32ef9532.patch"
        "https://github.com/FFmpeg/FFmpeg/commit/250471ea1745fc703eb346a2a662304536a311b1.patch"
        "https://github.com/yt-dlp/FFmpeg-Builds/raw/master/patches/ffmpeg/release/6.1/0001-avformat-webvttdec-Ignore-REGION-and-STYLE-chunks.patch"
        "jxl-id3v2-patch.patch")
b2sums=('SKIP'
        '555274228e09a233d92beb365d413ff5c718a782008075552cafb2130a3783cf976b51dfe4513c15777fb6e8397a34122d475080f2c4483e8feea5c0d878e6de'
        'SKIP'
        'SKIP'
        'SKIP'
        'SKIP'
        'SKIP')

prepare() {
  mv FFmpeg-n${pkgver} ffmpeg
  cd ffmpeg

patch -Np1 -i ../add-av_stream_get_first_dts-for-chromium.patch # https://crbug.com/1251779
  # Fix VDPAU vo
  patch -Np1 -i ../e9c93009fc34ca9dfcf0c6f2ed90ef1df298abf7.patch
  # Fix bug in av_fft_end
  patch -Np1 -i ../a562cfee2e214252f8b3f516527272ae32ef9532.patch
  patch -Np1 -i ../250471ea1745fc703eb346a2a662304536a311b1.patch

patch -p1 -i ../0001-avformat-webvttdec-Ignore-REGION-and-STYLE-chunks.patch
  patch -p1 -i ../jxl-id3v2-patch.patch
}

build() {
  cd ffmpeg
  # Temporarily add --disable-htmlpages to fix build
  mold -run ./configure \
    --prefix=/usr \
    --disable-debug \
    --disable-static \
    --disable-stripping \
    --disable-htmlpages \
    --enable-amf \
    --enable-avisynth \
    --enable-cuda-llvm \
    --enable-lto \
    --enable-fontconfig \
    --enable-frei0r \
    --enable-gmp \
    --enable-gnutls \
    --enable-gpl \
    --enable-ladspa \
    --enable-libaom \
    --enable-libass \
    --enable-libbluray \
    --enable-libbs2b \
    --enable-libdav1d \
    --enable-libdrm \
    --enable-libfreetype \
    --enable-libfribidi \
    --enable-libgsm \
    --enable-libharfbuzz \
    --enable-libiec61883 \
    --enable-libjack \
    --enable-libjxl \
    --enable-libmodplug \
    --enable-libmp3lame \
    --enable-libopencore_amrnb \
    --enable-libopencore_amrwb \
    --enable-libopenjpeg \
    --enable-libopenmpt \
    --enable-libopus \
    --enable-libplacebo \
    --enable-libpulse \
    --enable-librav1e \
    --enable-librsvg \
    --enable-librubberband \
    --enable-libsnappy \
    --enable-libsoxr \
    --enable-libspeex \
    --enable-libsrt \
    --enable-libssh \
    --enable-libsvtav1 \
    --enable-libtheora \
    --enable-libv4l2 \
    --enable-libvidstab \
    --enable-libvmaf \
    --enable-libvorbis \
    --enable-libvpl \
    --enable-libvpx \
    --enable-libwebp \
    --enable-libx264 \
    --enable-libx265 \
    --enable-libxcb \
    --enable-libxml2 \
    --enable-libxvid \
    --enable-libzimg \
    --enable-nvdec \
    --enable-nvenc \
    --enable-opencl \
    --enable-opengl \
    --enable-shared \
    --enable-version3 \
    --enable-vulkan

mold -run make -j$(nproc)
  mold -run make tools/qt-faststart -j$(nproc)
  mold -run make doc/ff{mpeg,play}.1 -j$(nproc)
}

package() {
  make DESTDIR="${pkgdir}" -C ffmpeg install install-man
  install -Dm 755 ffmpeg/tools/qt-faststart "${pkgdir}"/usr/bin/
}

Places

File PKGBUILD of Package ffmpeg (Revision 55e43128fbae1eaa7a7c87ede8866b6d)

Places