File PKGBUILD of Package targetcli-fb

pkgname=targetcli-fb
pkgver=3.0.0
pkgrel=2
pkgdesc="free branch of the targetcli LIO administration shell (iSCSI + Co)"
arch=('any')
url="https://github.com/open-iscsi/targetcli-fb"
license=('Apache')
depends=('python-rtslib-fb>=2.1.fb52' 'python-configshell-fb>=1.1.fb17'
         'python-dbus' 'python-gobject')
makedepends=(python-build python-hatch-vcs python-hatchling python-installer)
optdepends=('python-ethtool')
provides=('targetcli')
source=(https://github.com/open-iscsi/targetcli-fb/archive/v${pkgver}.tar.gz)
sha512sums=('b9a0dac75d979df7639b88f755194c41ea2156af7ebfa43aae27186ebe5e46ca7d9e24782c53da9d8915ca0772a7ba089dd725ce8c7cf05b1c0a85b7cd1fc929')

build() {
  cd "$srcdir/$pkgname-$pkgver"
  SETUPTOOLS_SCM_PRETEND_VERSION=$pkgver python -m build --wheel --no-isolation
  gzip --stdout targetcli.8 > "targetcli.8.gz"
  gzip --stdout targetclid.8 > "targetclid.8.gz"
}

package() {
  cd "$srcdir/$pkgname-$pkgver"
  python -m installer --destdir="$pkgdir" dist/*.whl

  install -D -m 644 targetcli.8.gz "$pkgdir/usr/share/man/man8/targetcli.8.gz"
  install -D -m 644 targetclid.8.gz "$pkgdir/usr/share/man/man8/targetclid.8.gz"
}