File PKGBUILD of Package cmake3

# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Contributor: Andrea Scarpino <andrea@archlinux.org>
# Contributor: Pierre Schmitz <pierre@archlinux.de>

pkgname=cmake3
pkgver=3.31.6
provides=(${pkgname%3}=$pkgver)
conflicts=(${pkgname%3})
pkgrel=3
pkgdesc='A cross-platform open-source make system'
arch=('x86_64')
url="https://www.cmake.org/"
license=('custom')
options=('staticlibs' '!lto')
options+=('!debug')
depends=(cppdap
         curl
         expat
         gcc-libs
         glibc
         hicolor-icon-theme
         jsoncpp
         libarchive
         libuv
         ncurses
         rhash
         zlib)
makedepends=(emacs
             git
             nlohmann-json
             python-sphinx
             qt6-base
             ccache)
optdepends=(
  'make: for unix Makefile generator'
  'ninja: for ninja generator'
  'qt6-base: cmake-gui'
)
source=("${pkgname%3}-${pkgver}.tar.gz::https://github.com/Kitware/cmake/releases/download/v${pkgver}/cmake-${pkgver}.tar.gz")
sha256sums=('SKIP')

build() {
  export LANG="en_US.utf8"

  cd ${pkgname%3}-${pkgver}
  ./bootstrap --prefix=/usr \
    CXXFLAGS="-fpermissive" \
    --system-libs \
    --qt-gui \
    --parallel=$(/usr/bin/getconf _NPROCESSORS_ONLN)
  make
}

package() {
  cd ${pkgname%3}-${pkgver}
  make DESTDIR="${pkgdir}" install

  rm -rf "$pkgdir"/usr/share/doc/cmake/html/_sources
  emacs -batch -f batch-byte-compile "${pkgdir}"/usr/share/emacs/site-lisp/cmake-mode.el
  install -Dm644 Copyright.txt "${pkgdir}"/usr/share/licenses/${pkgname%3}/LICENSE
}